" Define regions for ruby heredocs that tag the resulting string according to
" another support vim syntax.
" marker   - pattern to match in heredoc delimiter
" language - name of the vim language file (without .vim) 
function s:define_heredoc_syntax(marker,language)
  " Title-case the language name
  let l:caps_language = toupper(strpart(a:language,0,1)).strpart(a:language,1)
  
  " Load the other syntax definition
  let l:save_syntax = b:current_syntax
  unlet b:current_syntax
  execute 'syntax include @ruby'.l:caps_language.' syntax/'.a:language.'.vim'
  let b:current_syntax = l:save_syntax
  
  " Define additional heredoc definitions
  " First, those without the - (delimiter must be first thing on line)
  execute 'syn region ruby'.l:caps_language.'String matchgroup=rubyStringDelimiter start=+\%(\%(class\s*\|\%(\.\|::\)\)\_s*\)\@<!<<\z('.a:marker.'\)\ze\s*$+hs=s+2 end=+^\z1$+ contains=@rubyStringSpecial,@ruby'.l:caps_language.' fold'
  execute 'syn region ruby'.l:caps_language.'String matchgroup=rubyStringDelimiter start=+\%(\%(class\s*\|\%(\.\|::\)\)\_s*\)\@<!<<"\z('.a:marker.'\)"\ze\s*$+hs=s+2 end=+^\z1$+ contains=@rubyStringSpecial,@ruby'.l:caps_language.' fold'
  execute 'syn region ruby'.l:caps_language.'String matchgroup=rubyStringDelimiter start=+\%(\%(class\s*\|\%(\.\|::\)\)\_s*\)\@<!<<'."'".'\z('.a:marker.'\)'."'".'\ze\s*$+hs=s+2 end=+^\z1$+ contains=@ruby'.l:caps_language.' fold'
  execute 'syn region ruby'.l:caps_language.'String matchgroup=rubyStringDelimiter start=+\%(\%(class\s*\|\%(\.\|::\)\)\_s*\)\@<!<<`\z('.a:marker.'\)`\ze\s*$+hs=s+2 end=+^\z1$+ contains=@rubyStringSpecial,@ruby'.l:caps_language.' fold'
  
  " Those with - (delimiter may be preceded by whitespace)
  execute 'syn region ruby'.l:caps_language.'String matchgroup=rubyStringDelimiter start=+\%(\%(class\s*\|\%(\.\|::\)\)\_s*\)\@<!<<-\z('.a:marker.'\)\ze\s*$+hs=s+2 end=+^\s*\zs\z1$+ contains=@rubyStringSpecial,@ruby'.l:caps_language.' fold'
  execute 'syn region ruby'.l:caps_language.'String matchgroup=rubyStringDelimiter start=+\%(\%(class\s*\|\%(\.\|::\)\)\_s*\)\@<!<<-"\z('.a:marker.'\)"\ze\s*$+hs=s+2 end=+^\s*\zs\z1$+ contains=@rubyStringSpecial,@ruby'.l:caps_language.' fold'
  execute 'syn region ruby'.l:caps_language.'String matchgroup=rubyStringDelimiter start=+\%(\%(class\s*\|\%(\.\|::\)\)\_s*\)\@<!<<-'."'".'\z('.a:marker.'\)'."'".'\ze\s*$+hs=s+2 end=+^\s*\zs\z1$+ contains=@ruby'.l:caps_language.' fold'
  execute 'syn region ruby'.l:caps_language.'String matchgroup=rubyStringDelimiter start=+\%(\%(class\s*\|\%(\.\|::\)\)\_s*\)\@<!<<-`\z('.a:marker.'\)`\ze\s*$+hs=s+2 end=+^\s*\zs\z1$+ contains=@rubyStringSpecial,@ruby'.l:caps_language.' fold'
endfunction

" Define strings used in heredoc delimiters to identify particular embedded
" syntax
"let ruby_heredoc_c = "END_C"
"let ruby_heredoc_python = "END_PYTHON"
"let ruby_heredoc_html = "END_HTML"

if exists("ruby_heredoc_c")
  call s:define_heredoc_syntax(ruby_heredoc_c,"c")
endif

if exists("ruby_heredoc_python")
  call s:define_heredoc_syntax(ruby_heredoc_python,"python")
endif

if exists("ruby_heredoc_html")
  call s:define_heredoc_syntax(ruby_heredoc_html,"html")
endif